А сейчас bat скрипт для нового кластера. Или изменения существующего

@echo Скрипт развёртывания службы сервера кластера 1С
@echo .\NewCluster1CWportWcatalog.bat %%1 %%2 %%3
@echo %%1 - полный номер версии 1С:Предприятия
@echo %%2 - порт кластера 1С:Предприятия (пример 1541)
@echo %%3 - каталог с данными реестра кластера (без \ в конце)
@echo %%4 - Указатель функционала
@echo %%5 - Старое имя кластера
@echo off
if [%3] == [] goto :endline
set SrvUserName=<domain>\<domain_user>
set SrvUserPwd=<domain_user_password>
set ClustPort=%2
set Catalog=%3
set Prt=%ClustPort:~0,2%40
set FstDebugPrt=%ClustPort:~0,2%60
set LstDebugPrt=%ClustPort:~0,2%91
set SrvcName="1C:Enterprise 8.3 Server Agent (x86-64) %ClustPort% %~4"
set BinPath="\"C:\Program Files\1cv8\%1\bin\ragent.exe\" /srvc /agent /regport %ClustPort% /port %Prt% /range %FstDebugPrt%:%LstDebugPrt% /d %Catalog% /debug"
set Desctiption="Агент сервера 1С:Предприятия 8.3 (x86-64) %ClustPort% %~4 (%1)"
if not exist %Catalog% mkdir %Catalog%
if [%5] == [] (sc stop %SrvcName%) else (sc stop %5)
if [%5] == [] (sc delete %SrvcName%) else (sc delete %5)
sc create %SrvcName% binPath= %BinPath% start= auto obj= %SrvUserName% password= %SrvUserPwd% displayname= %Desctiption% depend= Tcpip/Dnscache/lanmanworkstation/lanmanserver
sc description %SrvcName% %Desctiption%
sc start %SrvcName%
:endline
@echo Пример запуска: C:\scripts\NewCluster1CWportWcatalog.bat 8.3.27.2214 2541 D:\1CSrvinfo\2540 "Бухгалтерия" "1C:Enterprise 8.3 Server Agent (x86-64) 2541 Бухгалтерия"

Очевидно, что скрипт нужно отредактировать там, где служебная учётка пользователя для старта службы.

Пример запуска из командной строки под админом:

NewCluster1CWportWcatalog.bat 8.3.27.2214 2541 D:\1CSrvinfo\2540 "Бухгалтерия" "1C:Enterprise 8.3 Server Agent (x86-64) 2541 Бухгалтерия"

тут 5 параметров при старте скрипта NewCluster1CWportWcatalog.bat:
1. 8.3.27.2214 - это номер х64 платформы, установленной в стандартное место C:\Program Files\1cv8\8.3.27.2214. Если почему то устанавливаете в другое место - вносите соответствующее исправление в скрипт. Чтобы запуск службы произошёл, не забудьте при установке платформы выбрать Сервер 1С
2. 2541 - основной порт кластера для подключения к базам 1С из списка баз
3.D:\1CSrvinfo\2540 - это папка для кэша кластера. Тут не должно быть пробелов, иначе скрипт не выполнится. Не используйте стандартную папку на системном диске. И временные sql базы и кэш кластера должны быть на отдельном самом быстром диске из имеющихся
4. "Бухгалтерия" - это функциональное имя, которое отразится в имени и описании службы. Можно пробелы
5. "1C:Enterprise 8.3 Server Agent (x86-64) 2541 Бухгалтерия" - это имя службы для замены. Если кластер новый - параметр не используем. Например, в кластере нужно обновить платформу, тогда между кавычками вставляем текущее имя кластера

Обычно я исправляю пример запуска в тексте скрипта в notepad++ и итог копирую в командную строку под админом.